--**************************** Reading Speed functions **************************--


-----------------------------------------------------------------------------------
-- ReadingIdle
--
--   Checks the reading delay timer and jumps to the next frame if the 
--   timer has not yet expired.  (Should be called from an on...idle handler).
--
on ReadingIdle
  global gTimedFrame
  global gTimeDelay
  --
  if (the frame = gTimedFrame) and (the timer >= gTimeDelay) then
    go to frame gTimedFrame + 1
  end if
end ReadingIdle


-----------------------------------------------------------------------------------
-- SetReadingSpeed
--
--   Sets the delay factor for sequentially displaying text.  Accepts values 
--   greater than zero (0) with 4 being the default.  Values represent factors 
--   of a quarter of a second.
--
on SetReadingSpeed speed
  global gReadingSpeed
  --
  if (speed > 0) then
    set gReadingSpeed to speed
  end if
  UpdateMenus
end SetReadingSpeed


-----------------------------------------------------------------------------------
-- StartReadingDelay
--
--   Starts the reading delay timer and sets the time delay according to the 
--   given delayFactor when entering a new frame.  (Should be called from 
--   the on...enterFrame handler).
--
on StartReadingDelay delayFactor
  global gTimedFrame
  global gTimeDelay
  global gReadingSpeed
  --
  if the frame <> gTimedFrame then  -- set delay & start timer on first time into frame
    set gTimeDelay = delayFactor * (15 * gReadingSpeed) 
    set gTimedFrame = the frame
    startTimer
  end if
end StartReadingDelay