'From Squeak3.2alpha of 7 October 2001 [latest update: #4599] on 29 December 2001 at 2:03:45 am'!
"Change Set:		FileListPatternNoScroll
Date:			29 December 2001
Author:			Doug Way

Cleans up somewhat ugly scrollbar in the pattern pane of the FileList.  (This is a problem with the new alternateWindowLook in short panes such as this with inboardScrollbars which are not hidden.)

Ideally, scrollbars should try to fit in a vertically squished height by first hiding the menu button, then scroll thumb, etc."!


!FileList class methodsFor: 'instance creation' stamp: 'dew 12/29/2001 01:37'!
addVolumesAndPatternPanesTo: window at: upperFraction plus: offset forFileList: aFileList 
	| row patternHeight volumeListMorph patternMorph divider dividerDelta |
	row _ AlignmentMorph newColumn hResizing: #spaceFill;
				 vResizing: #spaceFill;
				 layoutInset: 0;
				 borderWidth: 0;
				 layoutPolicy: ProportionalLayout new.
	patternHeight _ 25.
	volumeListMorph _ (PluggableListMorph
				on: aFileList
				list: #volumeList
				selected: #volumeListIndex
				changeSelected: #volumeListIndex:
				menu: #volumeMenu:)
				autoDeselect: false.
	patternMorph _ PluggableTextMorph
				on: aFileList
				text: #pattern
				accept: #pattern:.
	patternMorph acceptOnCR: true; hideScrollBarIndefinitely.
	divider _ BorderedSubpaneDividerMorph horizontal.
	dividerDelta _ 0.
	Preferences alternativeWindowLook
		ifTrue: [divider extent: 4 @ 4;
				 color: Color transparent;
				 borderColor: #raised;
				 borderWidth: 2.
			volumeListMorph borderColor: Color transparent.
			patternMorph borderColor: Color transparent.
			dividerDelta _ 3].
	row
		addMorph: (volumeListMorph autoDeselect: false)
		fullFrame: (LayoutFrame
				fractions: (0 @ 0 corner: 1 @ 1)
				offsets: (0 @ 0 corner: 0 @ patternHeight negated - dividerDelta)).
	row
		addMorph: divider
		fullFrame: (LayoutFrame
				fractions: (0 @ 1 corner: 1 @ 1)
				offsets: (0 @ patternHeight negated - dividerDelta corner: 0 @ patternHeight negated)).
	row
		addMorph: patternMorph
		fullFrame: (LayoutFrame
				fractions: (0 @ 1 corner: 1 @ 1)
				offsets: (0 @ patternHeight negated corner: 0 @ 0)).
	window
		addMorph: row
		fullFrame: (LayoutFrame
				fractions: upperFraction
				offsets: (0 @ offset corner: 0 @ 0)).
	Preferences alternativeWindowLook
		ifTrue: [row borderWidth: 2] ifFalse: [row borderWidth: 0]! !