'From Squeak2.9alpha of 13 June 2000 [latest update: #2447] on 28 July 2000 at 1:30:27 am'!
"Change Set:		BrowserShowAll-dew
Date:			28 July 2000
Author:			Doug Way

This changeset causes the  -- all --  message category to be automatically selected when a class is selected in a Browser, so that all messages always show up in the messages list.  The class definition template will still appear in the lower text pane when a class is selected (and when  -- all --  is selected).  To make things consistent, the class definition template also now re-appears when a message category is deselected (which is a good thing)."!


!Browser methodsFor: 'accessing' stamp: 'dew 7/28/2000 00:44'!
contentsSelection
	"Return the interval of text in the code pane to select when I set the pane's contents"

	messageCategoryListIndex > 1 & (messageListIndex = 0) 
		ifTrue: [^ 1 to: 500]	"entire empty method template"
		ifFalse: [^ 1 to: 0]  "null selection"! !

!Browser methodsFor: 'class list' stamp: 'dew 7/28/2000 01:10'!
classListIndex: anInteger 
	"Set anInteger to be the index of the current class selection."

	| className |
	classListIndex _ anInteger.
	self setClassOrganizer.
	messageCategoryListIndex _ 1.
	messageListIndex _ 0.
	self classCommentIndicated
		ifTrue: []
		ifFalse: [editSelection _ anInteger = 0
					ifTrue: [metaClassIndicated | (systemCategoryListIndex == 0)
						ifTrue: [#none]
						ifFalse: [#newClass]]
					ifFalse: [#editClass]].
	contents _ nil.
	self selectedClass isNil
		ifFalse: [className _ self selectedClass name.
					(RecentClasses includes: className)
				ifTrue: [RecentClasses remove: className].
			RecentClasses addFirst: className.
			RecentClasses size > 16
				ifTrue: [RecentClasses removeLast]].
	self changed: #classSelectionChanged.
	self changed: #classListIndex.	"update my selection"
	self changed: #messageCategoryList.
	self changed: #messageList.
	self contentsChanged! !

!Browser methodsFor: 'message category list' stamp: 'dew 7/28/2000 01:13'!
messageCategoryListIndex: anInteger 
	"Set the selected message category to be the one indexed by anInteger."

	messageCategoryListIndex _ anInteger.
	messageListIndex _ 0.
	editSelection _ 
		anInteger <= 1
			ifTrue: [#editClass]
			ifFalse: [#newMessage].
	contents _ nil.
	self changed: #messageCategorySelectionChanged.
	self changed: #messageCategoryListIndex.	"update my selection"
	self changed: #messageList.
	self contentsChanged
! !